' Listing 2. WmiSec.vbs

strFile = WScript.ScriptFullName

Set wmiFileSecuritySetting = _
	GetObject("winmgmts:Win32_LogicalFileSecuritySetting='" & strFile & "'")

' Fetch the security descriptor, and store it in wmiSD.
retval = wmiFileSecuritySetting.GetSecurityDescriptor(wmiSD)

' Retrieve the information from the security descriptor.
Set wmiDacl = wmiSD.Properties_.Item("Dacl")
Set wmiSacl = wmiSD.Properties_.Item("Sacl")

WScript.Echo strFile & " DACL" & vbCrLf & String(Len(strFile) + 5, "=")
For i = 0 To UBound(wmiDacl.Value)
	WScript.Echo "Trustee: " & _
		wmiDacl.Value(i).Properties_.Item("Trustee").Value.Properties_.Item("Name")
	WScript.Echo "   AccessMask: " & wmiDacl.Value(i).Properties_.Item("AccessMask").Value
	WScript.Echo "   AceFlags:   " & wmiDacl.Value(i).Properties_.Item("AceFlags").Value
Next

WScript.Echo vbCrLf &  strFile & " SACL" & vbCrLf & String(Len(strFile) + 5, "=")
For i = 0 To UBound(wmiSacl.Value)
	WScript.Echo "Trustee: " & _
		wmiSacl.Value(i).Properties_.Item("Trustee").Value.Properties_.Item("Name")
	WScript.Echo "   AccessMask: " & wmiSacl.Value(i).Properties_.Item("AccessMask").Value
	WScript.Echo "   AceFlags:   " & wmiSacl.Value(i).Properties_.Item("AceFlags").Value
Next


1


1