WEB LISTING 1: The RenderTableAttributes Procedure

Sub RenderTableAttributes(strTableName, oConn)

Dim strTemp, strQuery
Dim oRsColumnList
  
  '--- Get the list of columns/attributes/fields.
  strQuery = "  SELECT * FROM INFORMATION_SCHEMA.COLUMNS " + _
             "   WHERE TABLE_NAME='" + strTableName + "'" + _
             "ORDER BY ORDINAL_POSITION"
             
  Set oRsColumnList = oConn.Execute(strQuery)

  '--- Output the table header.
  Response.Write("<font size=+2>")
  Response.Write("Table: " + strTableName + "<br>")
  Response.Write("</font>")
  Response.Write("<br><b>Attributes</b>")
    
  Response.Write("<TABLE BORDER=1 CELLSPACING=0 CELLPADDING=2 WIDTH=100% bordercolor=Navy>")
  Response.Write("<TR>")  
  Response.Write("<TD align=center WIDTH='10%'>Serial No</TD>")
  Response.Write("<TD WIDTH='30%'>Field Name</TD>")
  Response.Write("<TD WIDTH='10%'>Nullable?</TD>")
  Response.Write("<TD WIDTH='20%'>DataType/Width</TD>")
  Response.Write("<TD WIDTH='30%'>Default</TD>")  
  Response.Write("</TR>")
  
  '--- Loop to parse to the list of columns.
  While Not oRsColumnList.EOF
  
    '--- Output the details of each column.
    Response.Write("<TR>")

    Response.Write("<TD align=center>" + CStr(oRsColumnList("ORDINAL_POSITION")) + "</TD>")
    Response.Write("<TD>" + oRsColumnList("COLUMN_NAME") + "</TD>")
    Response.Write("<TD>" + oRsColumnList("IS_NULLABLE") + "</TD>")

    strTemp = oRsColumnList("DATA_TYPE")

    If (Not IsNull(oRsColumnList("CHARACTER_MAXIMUM_LENGTH"))) Then
      strTemp = strTemp + " (" + CStr(oRsColumnList("CHARACTER_MAXIMUM_LENGTH")) + ")"
    Else
      strTemp = strTemp + " (" + CStr(oRsColumnList("NUMERIC_PRECISION")) + ")"
    End If

    Response.Write("<TD>" + strTemp + "</TD>")    
   
    If (Not IsNull(oRsColumnList("COLUMN_DEFAULT"))) Then
      Response.Write("<TD>" + oRsColumnList("COLUMN_DEFAULT") + "</TD>")
    Else
      Response.Write("<TD>&nbsp</TD>")
    End If
      
    Response.Write("</TR>")
     
    '--- Move to the next column.
    oRsColumnList.MoveNext

  Wend
    
  '--- End the table for columns.
  Response.Write("</TABLE>")    

  Set oRsColumnList = Nothing
End Sub